bolug bonner linux user group
news about wissen files archive hilfe suchen  

 

archive :: SchAN-User

druckfassung

SchAN-User

schan-user: Mailstation-Nachtrag

To: Schulen ans Netz Liste <schan-user@xxxxxxxxxxxxxxxxx>
Subject: schan-user: Mailstation-Nachtrag
From: pilzc@xxxxxxxxxxx (Christoff Pilz)
Date: Sat, 19 Feb 2000 13:14:11 +0100
Hallo,

Thomas Litsch schrieb:
> 
> Hallo,
> 
> Hermann Mang wrote:
> > ...
...
> 
> Wenn der Mailclient an einer eigenen Netzwerkkarte hängt, könntest du
> per crontab ein script starten, das die entsprechende Netzwerkkarte
> automatisch lädt und wieder entlädt. Hab ich aber leider gerade nicht
> rumliegen :-)
> Ich frage mich allerdings, warum die Kiste keinen Dauerkontakt haben
> soll? Damit die Schüler auf dem Weg zum Klo keine Mails lesen? Ohne
> diese Sperre wäre der Rechner auch in Freistunden nutzbar.
> 
> Und wichtig: er sollte eine PC-Wächterkarte haben!
> 
...schnipp

es geht auch super, mit 0,00 DM Aufwand, ich habe alle meine 30 Win95-WS
nach der Anleitung von
"Puschl Muschl" so ziemlich "dicht" bekommen.
Da ich die Adresse seiner Homepage nicht mehr finde, die Homepage und
seine Bsp. autoexec.bat als Anhang.

Nachtrag: Ich vergass die beiden wichtigen Dateien zum Abdichten (und
wieder freigeben) der Registry von A. Rittershofer.
Dort http://www.rittershofer.de oder noch zusätzlich als Anhang.

-- 
mfg Christoff

Christoff Pilz
Templin


schule: pilzc@xxxxxxxxxxxxxxxxxxxxxxxxxxx
privat: pilzc@xxxxxxxxxxx

Aus Puschl Muschl's Bastelkiste

Heute basteln wir uns eine Arme-Leute-Protektor-Karte


Hallo, liebe Kinder und liebe Erwachsenen, hier ist wieder Euer Puschl und hat Euch wieder etwas mitgebracht.

Freut Ihr Euch denn schon? Hmmm..., was wird es heute sein, fragt sich mancher. Wieder etwas Praktisches, was man so richtig gebrauchen kann?

Na, schauen wir doch mal nach. Ich hoffe, dass Ihr in der Zwischenzeit auch hübsch artig ward und mir keine Schande gemacht habt und dass Ihr mich auch täglich in Euer Nachtgebet eingeschlossen habt.

Wenn ich jetzt ein lautes "Aber ganz ganz bestimmt, lieber Puschl!" höre, dann ist es gut. Dann schnüre ich jetzt mal meinen großen Geschenkesack auf und schau nach, was sich darin für Euch befindet. Solange holt Euch mal was zu Trinken und ein bisschen was zum "Knabbern", damit Ihr auch schön den Mund haltet, wenn ich Euch jetzt was Neues erkläre:

Situation:

Viele Windows-Kisten sind zu administrieren. Die Schüler basteln immer wieder an den Einstellungen herum, teils unbeabsichtigt, teils aber voller Absicht. Man möchte recht gerne, dass die Rechner mal eine Grundeinstellung behalten und diese auch beibehalten, wenn die Rechner neu gestartet werden. Trotzdem sollen sich die Schüler - wenn sie wollen - durchaus auch mal einen anderen Desktop einstellen dürfen oder man möchte auch gerne einmal zeigen, wie ein Link auf dem Desktop angelegt wird.

Trotzdem gilt: Nach dem nächsten Start soll alles wieder so aussehen, wie es einmal war.

Natürlich kann die nachfolgende Anleitung nicht die bewährten Protektor-Karten ersetzen. Die Anleitung soll nur denjenigen helfen, die von ihrem Dienstherrn oder ihrer Dienstfrau (gibt es eigentlich solche?) kein Geld bekommen und ständig danach sehen müssen, wie sie die Rechner im Betrieb halten.

So, und jetzt die Anleitung:

Bei der "Arme-Leute-Protektor-Karte" geht um ein halbwegs ausgekluegeltes System an Datenabsicherung, mit welchem der Administrator der Systeme zwar nicht die ruhigen Naechte geniesst wie das Kollegium der Besitzenden (naemlich die mit "echter" Karte), aber doch ein Ansatz fuer diejenigen, denen der Dienstherr die Mittel gestrichen hat, um Rechner sicher zu schuetzen. Daher kommt im Nachgang eine AUTOEXEC.BAT, die dem gestressten Administrator wenigstens einige Sorgen abnehmen kann. Ich habe die Datei nachtraeglich ausreichend kommentiert und hoffe, dass sie dadurch leichter verstaendlich wird. Im wesentlichen stecken eigentlich nur reichliche DOS-Erfahrungen mit den Befehlen dahinter.

Also, Vorhang auf!

********* AUTOEXEC.BAT ********************

@echo off
rem Damit die nachfolgenden Zaubertricks niemand
rem so ohne weiteres sieht
cls
rem Dann eine kleine Meldung fuer Ungeduldige
echo Systemdaten werden eingelesen.
echo.
echo (c) 1999 durch Puschl, dem Hilfreichen!
echo.
echo.
echo Moment...

rem Sperren der Konsole
rem Mit nachfolgendem Befehl sorgt man dafuer, dass
rem keinerlei Meldungen mehr auf dem Bildschirm
rem erscheinen.
ctty nul

rem Systembezogene Einstellungen
rem ============================

rem Beschleunigung der nachfolgenden Plattenzugriffe
rem Funktioniert zumindestens unter Win95 so. Bei
rem Win98 hatte ich mal Probleme damit. Allerdings nicht
rem mehr, nachdem ich am Ende smartdrv bezueglich des
rem Laufwerks C: wieder deaktivierte
rem Der Sinn ist einfach nur, dass die nachfolgenden
rem Kopierbefehle ein bisschen laenger ablaufen, sonst
rem kann der Bootvorgang schon mal so seine 20 bis 30
rem Sekunden dauern
smartdrv

rem Aufstartprotokollierung
rem Datetime ist einfach ein kleines Turbopascalprogram,
rem welches ich geschrieben habe und welches Datum und
rem Uhrzeit auf der Standardausgabe schreibt und somit
rem in eine Datei umgeleitet werden kann. Damit komme
rem ich den Schuelern mit der Rede "Aber ich hatte doch
rem den PC noch nicht einmal eingeschaltet" auf die
rem Spruenge. Leider haben auch Lehrer diese Marotte
rem des "Ich wars nicht, ich habs nicht mal ein geschaltet".
rem Gute Protokolle tun da wirkliche Wunder. Doch bitte
rem vorher nachsehen, ob Datum und Uhrzeit richtig gehen,
rem sonst tut man schnell jemandem Unrecht. Und da sei dieser
rem aeltere Herr vor, wie heisst er doch gleich...
rem hmmmm..... ah ja "Gott".
c:\windows\datetime >> c:\windows\sysstart.ptk

rem Allgemeine Systemeinstellungen
rem Naja, das uebliche Zeuch...
mode con codepage prepare=((437) C:\WINDOWS\COMMAND\ega.cpi)
mode con codepage select=437
rem Tastatur scharf machen, ich hasse lahme Tastaturen
rem Das wird auch in Windows eingestellt, aber manchmal
rem moechte man ja nur die DOS-Oberflaeche.
mode con rate=32 delay=1
keyb gr,,C:\WINDOWS\COMMAND\keyboard.sys
rem sortierte Inhaltsverzeichnisse auf DOS-Ebene
set dircmd=/o
rem C:\TEMP ist fuer mich schneller erreichbar als
rem C:\WINDOWS\TEMP, daher nur...
set temp=c:\temp
set tmp=c:\temp

rem Korrektur der Plattenlabels
rem Denn manche Leute schreiben gerne in das Label
rem freche Sachen hinein, zum Beispiel "ARSCH" oder
rem sonst was. Da bleibt darin, was darin gehoert.
label c: puschl
rem (Man kann auch gerne was anderes nehmen ;-))

rem Ruecksichern der Systemregistrierung und der INI-Dateien
rem Dazu erst mal die alten Teile komplett loeschen
deltree /y c:\windows\system.dat
deltree /y c:\windows\user.dat
rem Und da ich eine mir genehme Registrierung einmal
rem erstellt habe und diese mit dem Kuerzel DA_ abge-
rem speichert habe, kann man die jederzeit zurueckkopieren.
copy c:\windows\system.da_ c:\windows\system.dat
copy c:\windows\user.da_ c:\windows\user.dat
rem Das gleiche auch mit den INIs. Die habe ich alle vorher in
rem IN_ kopiert, jetzt kopiere ich sie von dort zurueck.
rem Bildschirmschoner-Texte stehen beispielsweise in so was
rem drinnen und noch viele andere Sachen.
deltree /y c:\windows\*.ini
copy c:\windows\*.in_ c:\windows\*.ini

rem Stammverzeichnis aufraeumen
rem Denn im Stammverzeichnis hat hier nichts zu suchen.
rem Ich mag es nicht, wenn Leute das als Aufbewahrungsort
rem fuer Dateien nehmen. Wofuer gibt es Unterverzeichnisse?
rem daher mal zunaechst alle Attribute weg.
attrib c:\*.* -a -s -h -r
rem Aber ganz schnell an IO.SYS wieder dran.
rem Sonst gibt es Aerger.
attrib c:\io.sys +s +h +r
rem Dann COMMAND.COM, CONFIG.SYS, AUTOEXEC.BAT
rem und MSDOS.SYS schuetzen.
attrib c:\command.com +r
attrib c:\config.sys +r
attrib c:\autoexec.bat +r
attrib c:\msdos.sys +r
rem und den Rest gnadenlos killen. Da leider der DEL-Befehl
rem mit *.* eine Bestaetigung braucht, wird der Buchstabe
rem "j" mittels Dateiumleitung aus einer Datei geholt,
rem die ich vorher mit dem Editor angelegt habe und
rem in der sich nur der Buchstabe "j" und das Return
rem befinden. Vorsicht: Mit deltree kann man hier nicht
rem arbeiten, der putzt alles weg. DEL laesst aber die
rem Dateien uebrig, die das R-Attribut dran haben.
del c:\*.* < c:\windows\ja.dat

rem Loeschen ueberfluessiger Verzeichnisse.
rem Damit killt man volle Papierkoerbe sowie alle
rem Ablagerungen auf dem Desktop, die ich dort nicht mag.
rem Ausserdem werden gleichzeitig alle besuchten
rem Internetseiten geloescht, ebenso das komplette
rem Startmenue. Wie man das wieder herstellt, kommt
rem spaeter noch dran. RECENT wird ebenfalls platt-
rem gemacht, das ist der Ordner mit den letzten Dateien,
rem die benutzt wurden. Das geht keinen was an.
deltree /y c:\temp
deltree /y c:\recycled
deltree /y c:\windows\cookies
deltree /y c:\windows\desktop
deltree /y c:\windows\downlo~1
deltree /y c:\windows\favori~1
deltree /y c:\windows\history
deltree /y c:\windows\recent
deltree /y c:\windows\startm*
deltree /y c:\windows\temp
deltree /y c:\windows\tempor~1

rem Neuanlegen notwendiger Verzeichnisse
md c:\temp
md c:\windows\temp

rem Verbiegen des Diskettenlaufwerks, damit es nicht mehr
rem funktioniert. Das erspart die Laufwerksschloesser,
rem wenn es auch nur ein recht geringer Schutz ist.
rem Immerhin besser, als keiner. Ich denke da vor allem
rem auch an Computerviren.
subst a: c:\temp

rem Anmeldedateien loeschen. Ist gut gegen die Aus-
rem spaeh-Spezialisten, die mit Back-Orifice arbeiten und
rem aehnlichen unangenehmen ;-))) Dingen.
rem Allerdings werden gewuenschte PWL-Dateien wieder
rem aus einer zuvor angelegten Sicherheitskopie ins
rem Original kopiert, damit der Rechner nicht bei jedem
rem Neustart das Anmeldepasswort fuer die Win-Anmeldung
rem verlangt. Das ist naemlich unsinnig und vollkommen
rem ueberfluessig.
deltree /y c:\windows\*.pwl
copy c:\windows\*.pw_ c:\windows\*.pwl

rem Windows-Startdatei
rem Die habe ich mir angelegt, die bewirkt, dass der Rechner
rem sich nach Herunterfahren von WIN nicht mehr abstellt.
rem Das automatische Abstellen empfinde ich persoenlich
rem als eine Versklavung durch Microsoft. Denn wer sagt denn,
rem dass ich nach Herunterfahren des Rechners nicht mit
rem was anderem arbeiten moechte, mit DOS oder mit Linux.
rem Wenn ich den Rechner abschalten moechte, bemuehe ich
rem dafuer den Ausschalter, nichts anderes.
rem FREEDOM FOR PUSCHL AND THE REST OF THE WORLD
rem INCLUDING FRIENDS IN BRAUNSCHWEIG!
deltree /y c:\windows\win.bat
copy c:\windows\win.ba_ c:\windows\win.bat

rem Sicherung des Startmenues in Grundeinstellung bringen
rem Die Datei sichern.pif bzw. sichern.bat enthaelt
rem Befehle, mit denen das Startmenue in den Ausgangszustand
rem gebracht wird.
deltree /y c:\windows\sichern.pif
copy c:\windows\sichern.pi_ c:\windows\sichern.pif

rem Programmbezogene Einstellungen
==================================

rem Outlook (Standard)
rem Adressbuecher und aehnliches Gemurks killen. Das
rem geht den Nachfolger naemlich nichts an.
rem Man muss nur rausfinden, ob das wirklich auch die
rem Orte sind. Bei mir sind es diese, daher weg damit.
del c:\windows\*.pst
copy c:\windows\*.ps_ c:\windows\*.pst

rem Outlook-Express
rem Genau das gleiche mit Outspuck-Express. Weg damit
rem mit dem ganzen Geroedel.
deltree /y c:\windows\anwend~1

rem Netscape habe ich augenblicklich nicht mit
rem beruecksichtigt. Da muss mal ein Nachtrag kommen.

rem Word
rem Hat jemand die Standardeinstellungen von Word
rem veraendert? Das moechte man nicht. Also loeschen
rem und die Original-Datei, wie ich sie erstellt habe,
rem dorthin kopieren, womit der Rechner nach Aufstart
rem arbeitet.
rem Auch hier bitte nachschauen. Andere Wordversionen
rem koennten vielleicht andere Speicherorte benutzen.
rem Und immer dran denken, man darf keine langen
rem Dateinamen nehmen, wir sind noch in DOS
rem (Windows ist ja bekanntermassen nach wie vor lediglich
rem ein grafischer Aufsatz auf DOS)
deltree /y c:\progra~1\micros~1\vorlagen\normal.dot
copy c:\progra~1\micros~1\vorlagen\normal.do_
c:\progra~1\micros~1\vorlagen\normal.dot

rem An diese Stelle weitere Anpassungen fuer andere Pro-
rem gramme, die eingesetzt werden.

rem Und Abschalten des Festplatten-Caches.
rem Denn jetzt sind wir mit der Kopiererei fertig.
rem smartdrv c-

rem Freigeben der Konsole
rem Jetzt kann die Konsole wieder freigegeben werden, denn
rem jetzt kommen noch ein paar nette Begruessungsmeldungen
rem und dann ists auch schon gut.
ctty con:

rem Begruessungstext
cls
echo Der Rechner wurde korrekt gestartet.
echo.
echo Puschl Muschl wuenscht allen einen schonen Tag und
echo einen geruhsamen Lebensabend!
echo
echo Viel Spass bei der Arbeit!
echo.
echo.

********************** FIN ************************

So. Was macht man jetzt, wenn ein Schueler einem die AUTOEXEC.BAT verstellt? Nun, dieser Schueler wird garantiert WIN starten. Und jetzt setzen wir einen Befehl in die C:\WINDOWS\WIN.INI, naemlich

run=c:\windows\sichern.bat

Und darin stehen weitere Befehle. Darin wird die AUTOEXEC.BAT aus dem Startmenue geloescht und durch eine "versteckte" Version ersetzt. Naja, also gewiefte Schueler finden das sicherlich raus, aber der "Kleine Schlaumeier", der im Stammverzeichnis seinen Mitschuelern gross vorfuehrt, wie er den Puschl aergern kann, wird sich schwer wundern, wenn nach Neustart des Rechners wieder alles beim alten ist.

Ausserdem wird damit das Startmenue durch den XCOPY-Befehl wieder hergestellt. Das geht naemlich jetzt erst, weil das Startmenue lange Dateinamen hat.

In C:\MSDOS.SYS sollten noch folgende Befehle enthalten sein:

BOOTGUI=0
LOGO=0

Damit unterbindet man diesen schwachsinnigen (SCNR) Himmel. Ich kann ihn einfach nicht ausstehen. Grossmutter findet ihn auch nicht besonders. Und meine kleine Schwetsr hat sich dort einen suessen Teddy hingebastelt.

Damit der Rechner nach Herunterfahren wieder auf C:\ steht, empfiehlt sich noch, in C:\WINDOWS mit dem Befehl

del log*.sys

alle Bilder (dieses braune Zeuchs) wegzuschmeissen.

Genug erst mal dazu.

Und nochmals: Weniger Arbeit in der Tat macht der Besitz der Schutzkarten. Aber wieviele Leute haben hier in der Liste schon gejammert, dass keine Gelder da sind. Lieber den freiwillig arbeitenden Lehrer Ueberstunden machen lassen, der richtet schon seit Zeug, er moechte ja selber, dass er richtig arbeiten kann. Leute, es ist wahrhaft traurig, es ist wirklich furchtbar, was da manchen zugemutet wird. Ich habe mit all diesen ein sehr grosses Mitgefuehl!

So, liebe Kinder und liebe Erwachsenen, habe Ihr auch alles schön verstanden? Wenn ja, dann sagt jetzt artig "Danke, lieber Puschl!" und schreibt ein kleines Sprüchlein in Puschls Gästebuch, aber nur artige und anständige Sachen, sonst schmeißt es der Puschl wieder raus!

Herzliche Grüße sagt Euch allen

Euer Puschl!

Und da geht es wieder zurück zur Home-Page von Puschl Muschl

Attachment: autoexec.bat
Description: application/unknown-content-type-batfile

Attachment: open.reg
Description: application/unknown-content-type-regfile

Attachment: close.reg
Description: application/unknown-content-type-regfile

 « Vorige im Thread  Dieser Thread  Nächste im Thread » 

 

seitenanfang


 

news about wissen files archive hilfe suchen  
kontakt letzte änderung: 20.02.2000